Include (KZLibrary, KZISSetup)

/// <p>Projekt: <b>KZIS</b>
/// <p>Author : <b>M. Brousek</b> 				
/// <p>Created: <b>10.9.2010</b>
/// <p>Description: <b>Služba pro přenos dat ze SAPu předaných prostřednictvím CSV souboru.</b>
/// <p>Viz též výkonná metoda <METHOD>OnProcessInput</METHOD>
/// 	<p>Třída zachycuje a zpracovává události typu <CLASS>KZIS.Data.TS.Events.ekCSVFile</CLASS>
Class KZIS.BS.SAP.SHandleCSVFile Extends Ens.BusinessService [ ProcedureBlock ]
{

Parameter ADAPTER = "EnsLib.File.InboundAdapter";

/// Přesune soubor ze sdílené složky do interní složky systému k následnému zpracování.
Method MoveFile(pIncomingFile As %String, pFileName As %String)
{
	set tDataFileName = $$$KZISDataFullPath_$$$SAPIncomingDir_pFileName
	if ##class(%File).Exists(tDataFileName) do ##class(%File).Delete(tDataFileName)
	set tSC = ##class(%File).Rename(pIncomingFile, tDataFileName)
	if 'tSC $$$LOGERROR("Could not move '"_pIncomingFile_"' to KZIS internal directory: "_tDataFileName)
}

/// Spustí proces, který importuje data do interní DB systému následně je  v rámci téže transakce <b>přenese do systému Apothéké</b>. 
/// Přenášená datová entita (a tedy i daný soubor) je dána kódem typu příslušné transakce, 
/// zdanému v parametru <VAR>pTansKindCode</VAR>
Method ProcessSAPCodebooksToApo(pTansKindCode As %String)
{
	set tRequest = ##class(KZIS.Msg.MW.BPDataRequest).%New()
	set tRequest.TransactionKindCode = pTansKindCode
	set tRequest.Event = ##class(KZIS.Data.TS.Events.ekCSVFile).MarkEvent()
	// Call operation async	
	set tSC = ..SendRequestSync("PSAPCodebooksToApo", tRequest)
	
	// Quit on error
	if $$$ISERR(tSC) {		
		do %System.Status.Decompose(tSC, .tErrList)
		$$$LOGERROR(.tErrList)
		quit tSC
	}	
	quit tSC
}

/// Spustí proces, který <b>importuje data do interní DB systému</b>. 
/// Přenášená datová entita (a tedy i daný soubor) je dána kódem typu příslušné transakce, 
/// zdanému v parametru <VAR>pTansKindCode</VAR>
Method ProcessSAPImportCSVFile(pTansKindCode As %String)
{
	set tRequest = ##class(KZIS.Msg.MW.BPDataRequest).%New()
	set tRequest.TransactionKindCode = pTansKindCode
	set tRequest.Event = ##class(KZIS.Data.TS.Events.ekCSVFile).MarkEvent()
	// Call operation async	
	set tSC = ..SendRequestSync("PSAPImportCodebookFiles", tRequest)
	
	// Quit on error
	if $$$ISERR(tSC) {		
		do %System.Status.Decompose(tSC, .tErrList)
		$$$LOGERROR(.tErrList)
		quit tSC
	}	
	quit tSC
}

/// Zkontroluje délku souboru, jehož jméno je zadáno v parametru <VAR>pFileName</VAR>
/// V případě, že je daný soubor prázdný nebo neexistuje vrátí hodnotu <i>True</i> a zapíše
/// informaci do logu jako WARNING. V případě existující neprázdného souboru vraci <i>False</i>.
Method CheckEmptyFile(pFileName As %String) As %Boolean
{
	
	q:(##class(%File).GetFileSize(pFileName)>0) 0
	$$$LOGWARNING("SAP incoming file error: File is empty '"_pFileName_"'")
	q 1
}

/// Zpracovává soubory, nacházející se ve sdílené složce vyhrazené systému SAP. 
/// Názvy složek, kde se soubory očekávají, a maska názvů souborů jsou uloženy v definici 
/// <i>KZISSetup.inc</i> a v setupu projektu <CLASS>KZIS.MW.Setup</CLASS>.
/// Defaultní název cesty je "shared_files/kzis/sap/in", defaultní hodnota masky pak "SAP_*".
/// <p>Zpracovávané soubory jsou přesunuty do interní složky systému a následně je spuštěn proces, 
/// který dané soubory zpracuje. Ze zpracování jsou vyloučeny soubory s nulovou délkou. 
/// Jejich výskyt je zaznamenán do logu jako WARNING. Stejně tak jsou do logu zaznamenány soubory,
/// jejichž název neodpovídá žádnému zpracovávanému souboru.
Method OnProcessInput(pInput As %FileCharacterStream, pOutput As %RegisteredObject) As %Status
{
	set FileName = ##class(%File).GetFilename(pInput.Filename)
	if FileName = $$$SAPCostCentersFileName
	{
		q:..CheckEmptyFile(pInput.Filename) $$$OK
		do ..MoveFile(pInput.Filename, $$$SAPCostCentersFileName)
		do ..ProcessSAPCodebooksToApo($$$tkcSAPCostCenters)
	}
	elseif FileName = $$$SAPVendorsFileName
	{
		q:..CheckEmptyFile(pInput.Filename) $$$OK
		do ..MoveFile(pInput.Filename, $$$SAPVendorsFileName)
		do ..ProcessSAPCodebooksToApo($$$tkcSAPVendors)
	}
	elseif FileName = $$$SAPCustomersFileName
	{
		q:..CheckEmptyFile(pInput.Filename) $$$OK
		do ..MoveFile(pInput.Filename, $$$SAPCustomersFileName)
		do ..ProcessSAPCodebooksToApo($$$tkcSAPCustomers)
	}
	elseif FileName = $$$SAPBookingOrdersFileName
	{
		q:..CheckEmptyFile(pInput.Filename) $$$OK
		do ..MoveFile(pInput.Filename, $$$SAPBookingOrdersFileName)
		do ..ProcessSAPCodebooksToApo($$$tkcSAPBookingOrders)
	}
	elseif FileName = $$$SAPMGroupXBClassFileName
	{
		q:..CheckEmptyFile(pInput.Filename) $$$OK
		do ..MoveFile(pInput.Filename, $$$SAPMGroupXBClassFileName)
		do ..ProcessSAPImportCSVFile($$$tkcSAPMGroupXBClass)
	}
	else
	{
		$$$LOGWARNING("SAP incoming file error: Unexpected filename '"_pInput.Filename_"'")
	}
	quit $$$OK
}

/// Callback method called just after %OnNew()
/// <p>Metoda zajistí načtení nastavení (settings) <i>FilePath</i> a <i>FileSpec</i> z hodnot, 
/// uložených v definici <i>KZISSetup.inc</i> a v Setupu projektu (globals). 
/// Viz též třída <CLASS>KZIS.MW.Setup</CLASS>, 
/// která zprostředkovává přístup k hodnotám stupu, uložených v golobals.
Method OnInit() As %Status
{
	set ..Adapter.FilePath = $$$SharedFilesFullPath_$$$SAPIncomingDir
	set ..Adapter.FileSpec = $$$SAPIncomingCSVFilesSpec
	$$$LOGINFO("SAP incoming files full path: "_..Adapter.FilePath)
	$$$LOGINFO("SAP incoming codebook files spec: "_..Adapter.FileSpec)
	Quit $$$OK
}

}